Días entre dos fechas en Excel: cómo contarlos

Para contar los días entre dos fechas en Excel basta con restarlas: =B2-A2. Si solo quieres los laborables, usa DIAS.LAB, que descuenta fines de semana y festivos, y para años o meses completos, SIFECHA.

Descargar el Excel con todos los ejemplos

En el Excel cambias las fechas de las celdas amarillas y todos los resultados se recalculan. Al lado de cada resultado tienes la fórmula tal como la verás en Excel en español, que separa los argumentos con punto y coma.

Resumen rápido

Qué quieres saber	Fórmula	Del 1 de octubre al 31 de diciembre de 2026
Días naturales	=B2-A2	91
Días naturales con función	=DIAS(B2;A2)	91
Días naturales contando el primero y el último	=B2-A2+1	92
Laborables de lunes a viernes	=DIAS.LAB(A2;B2)	66
Laborables sin los festivos de la lista	=DIAS.LAB(A2;B2;Festivos)	63
Laborables de lunes a sábado	=DIAS.LAB.INTL(A2;B2;11;Festivos)	76

A2 es la fecha inicial y B2 la final. Festivos es una lista de fechas que escribes en otra columna. En el ejemplo son tres fiestas nacionales de 2026: 12 de octubre, 8 de diciembre y 25 de diciembre.

Restar las dos fechas

Excel guarda cada fecha como un número de días, así que la resta da directamente los días que hay entre una y otra. Escribe la fecha inicial en A2, la final en B2 y en otra celda =B2-A2.

Si el resultado sale como una fecha rara en vez de un número, cambia el formato de esa celda a Número o General. Y fíjate en si quieres contar los dos extremos. Del 1 al 31 de diciembre hay 30 días de diferencia, pero si cuentas el día 1 y el día 31 son 31. En ese caso suma uno: =B2-A2+1.

La función DIAS

Hace lo mismo que la resta, pero con nombre. Su sintaxis es DIAS(fecha_final; fecha_inicial), con la fecha final primero. Si las pones al revés, sale el mismo número en negativo.

Días laborables con DIAS.LAB

DIAS.LAB cuenta los días de lunes a viernes entre dos fechas y, si se lo das, descuenta también una lista de festivos. La sintaxis es DIAS.LAB(fecha_inicial; fecha_final; [vacaciones]). El tercer argumento es opcional y puede ser un rango de celdas con fechas.

Del 1 de octubre al 31 de diciembre de 2026 salen 66 días laborables. Con los tres festivos del ejemplo en la lista, 63. La función cuenta también el primer y el último día si son laborables.

Los festivos tienen que ser fechas de verdad, no texto. Microsoft recomienda escribirlas con la función FECHA o que salgan de otra fórmula. Las fiestas cambian según la comunidad autónoma y el municipio, así que pon las de tu calendario.

Otros fines de semana con DIAS.LAB.INTL

Si no descansas sábado y domingo, DIAS.LAB.INTL te deja decir qué días son fin de semana. La sintaxis es DIAS.LAB.INTL(fecha_inicial; fecha_final; [fin_de_semana]; [vacaciones]). Estos son algunos de los números que acepta:

Número	Días de descanso
1 u omitido	Sábado y domingo
2	Domingo y lunes
7	Viernes y sábado
11	Solo domingo
17	Solo sábado

También acepta una cadena de siete ceros y unos que empieza por el lunes, donde 1 es día de descanso. Así, «0000011» equivale a sábado y domingo. Con descanso solo el domingo, el periodo del ejemplo tiene 76 días laborables. Con descanso viernes y sábado, 64.

Años y meses completos con SIFECHA

Para la edad, la antigüedad en un trabajo o el tiempo de un contrato lo que interesa son años y meses, y para eso está SIFECHA: SIFECHA(fecha_inicial; fecha_final; unidad). La unidad va entre comillas:

• «Y» da los años completos.
• «M» da los meses completos.
• «D» da los días.
• «YM» da los meses que sobran después de contar los años completos.
• «YD» da los días que sobran después de contar los años completos.

Del 15 de marzo de 2019 al 30 de septiembre de 2026 hay 7 años completos, 90 meses completos y 2.756 días. Para que salga escrito, junta dos SIFECHA:

=SIFECHA(A2;B2;"Y")&" años y "&SIFECHA(A2;B2;"YM")&" meses"

Con las fechas del ejemplo, eso da «7 años y 6 meses». Para calcular una edad a día de hoy, cambia la fecha final por HOY(): =SIFECHA(A2;HOY();"Y").

Microsoft avisa de dos cosas. Excel mantiene SIFECHA por compatibilidad con libros antiguos de Lotus 1-2-3, y la unidad «MD» puede dar un resultado inexacto, un cero o un número negativo, así que mejor no usarla.

En la web hay otra entrada con una hoja para calcular fechas en Excel, centrada en sacar los años que han pasado desde una fecha de nacimiento.